#! /bin/csh -f
#
set verbose
#
#  The following symbols define the GDS version and target location.
set gdsdir = /opt/dmt
set gdsrev = 2.8.1
set rootdir=/opt/CERN/root_4.00-03
#
#  Standard cvs location
#
set cvs_user=readonly
set cvs_server=ldas-sw.ligo.caltech.edu
set cvs_archive=/ldcg_server/common/repository_gds
setenv CVSROOT :pserver:${cvs_user}@${cvs_server}:$cvs_archive
#
#    make sure user has logged in...
#
if ( ! `grep ${cvs_server}: $HOME/.cvspass | grep -c ${cvs_archive}` ) then
    unset verbose
    echo "You have not logged in to the GDS cvs repository. to log in type:"
    echo " "
    echo "    cvs -d $CVSROOT login"
    echo " "
    echo "and enter the appropriate password"
    exit 1
endif
#
#  Select the right O/S
#
switch(`uname -s`)
case SunOS:
    set arch = solarisgcc
    breaksw
case Linux:
    set arch = linux
    breaksw
default:
    set arch = Unknown
    breaksw
endsw
#
#   Drag in the cvs repository
#
mkdir -p $gdsdir/cvs
cd $gdsdir/cvs
set gdstag=`echo gds_$gdsrev | sed -e "s/\./_/g"`
if (! -f gds/CVS/Tag || "`cat gds/CVS/Tag`" != "N$gdstag" ) then
    echo "Downloading GDS software version: $gdstag"
    if ( -d gds ) cvs release -d gds
    cvs get -r $gdstag gds
else
    echo "Updating GDS software version: $gdstag"
    cvs update -d gds
endif
#
setenv ROOTSYS $rootdir
setenv GDSBUILD framecpp
cd gds
./configure $arch
make -C External
make
make prefix=$gdsdir/rev_$gdsrev install